8.6 Numbered target markers

The numbered target markers feature, introduced with CQP v3.4.16, provides a work-around solution for marking up to 10 anchor positions in a finite-state query (with support from wrapper scripts, as discussed below).

• In addition to the implicit match and matchend anchors, CQP queries allow a single additional token pattern to be marked with an @ sign, setting the target anchor to the matching corpus position. If multiple target markers are specified, the one encountered last during query evaluation “wins”.

• Users would quite often like to mark multiple positions, however. Consider the query below, which has three additional tokens of interest (adverb, first adjective, second adjective); only one of them can be marked with @.

  > [pos="DT"] [pos="RB"] [pos="JJ"] [pos="JJ"] [pos="N.*"];

• It is now possible to mark up to 10 potential targets with numbered markers @0 ... @9. Only two of them are active at a given time, controlled by the user options AnchorNumberTarget (ant) and AnchorNumberKeyword (ank).

  > [pos="DT"] @0[pos="RB"] @1[pos="JJ"] @2[pos="JJ"] [pos="N.*"];

• The query above will mark the adverb position as target and the first adjective as keyword, because @0 and @1 are active by default. Re-run the query after changing AnchorNumberTarget in order to mark the second adjective as target, instead of the adverb.

  > set AnchorNumberTarget 2;
> [pos="DT"] @0[pos="RB"] @1[pos="JJ"] @2[pos="JJ"] [pos="N.*"];

• It is invalid to map both anchors to the same numbered target, and the set command will reject such a change with an error message. Scripts therefore need to keep track of the current settings when making changes; it is recommended always to map the two anchors to non-overlapping pairs of anchors (e.g. @0 and @1, @2 and @3, etc.).

• The main purpose of the new feature is to enable wrapper scripts to simulate up to 10 target anchor positions in a way that is fully compatible with CQP macros and does not require any custom extensions, so queries can be tested in an interactive CQP session or in CQPweb.

• Since the wrapper cannot know which numbered target markers are used in a query (especially with nested macros), every query has to be run 5 times, collecting the target and keyword positions from each run and combining them into a single table at the end. In CQP v3.4.31+, the extra runs can be executed as anchored queries in order to reduce the overhead for complex search patterns in large corpora.²³

• Here is an example how a wrapper might process such a query:²⁴

  > set AnchorNumberTarget 0; set AnchorNumberKeyword 1;
> Result = [pos="DT"] @0[pos="RB"] @1[pos="JJ"] @2[pos="JJ"] [pos="N.*"];
> Temp = <<Result/>> ( [pos="DT"] @0[pos="RB"] @1[pos="JJ"] @2[pos="JJ"] [pos="N.*"] );
> dump Temp; # obtain matching ranges and first two target anchors @0 and @1
> set AnchorNumberTarget 2; set AnchorNumberKeyword 3;
> Temp = <<Result/>> ( [pos="DT"] @0[pos="RB"] @1[pos="JJ"] @2[pos="JJ"] [pos="N.*"] );
> dump Temp; # obtain next two target anchors @2 and @3
  $\vdots$
  > set AnchorNumberTarget 8; set AnchorNumberKeyword 9;
> Temp = <<Result/>> ( [pos="DT"] @0[pos="RB"] @1[pos="JJ"] @2[pos="JJ"] [pos="N.*"] );
> dump Temp; # obtain last two target anchors @8 and @9
  

• NB: The wrapper script should not forget to reset AnchorNumberTarget and AnchorNumberTarget to their previous or default settings (and to re-activate the main corpus if anchored subqueries are used before CQP v3.4.31).

• For backward compatibility, the plain @ marker unconditionally sets the target anchor, regardless of the value of AnchorNumberTarget. Queries should never mix @ with the numbered potential target markers.

• All target markers can be followed by an optional colon : similar to the notation used for labels (including @: for the unconditional target).

  > [pos="DT"] @0:[pos="RB"] @1:[pos="JJ"] @2:[pos="JJ"] [pos="N.*"];

  This simplifies CQP macros, which do not have to distinguish between label names and target markers passed as arguments.

• CQP macros intended to be embedded in more complex queries should always use parameterized target markers. Consider the following definition of a macro matching simple noun phrases:

  MACRO np($0=MarkNoun $1=MarkAdj)
  (
    [pos="DT"]? [pos="RB"]? $1[pos="JJ.*"]* $0[pos="NN.*"]
  )
  ;
  MACRO np($0=MarkNoun)
  /np["$0", ""]
  ;
  MACRO np(0)
  /np["", ""]
  ;
  

• Invocations of the above macro can now specify numbered target markers to be placed on the head noun and last adjective in the NP, respectively. The markers must be quoted as macro arguments; an empty string "" omits the corresponding marker. The two additional macros simulate default values (no marker) for both arguments.

• As an example, let us search for the pattern “NP Prep NP” and extract the head noun and adjective (if present) of the first NP, as well as the preposition and head noun of the PP (e.g. this festive season of the year).

  > /np["@1", "@0"] @2[pos="IN"] /np["@3"];

  This query applies @0 to the adjective of the first NP, @1 to its head noun, @2 to the preposition and @3 to the head noun of the PP.

• Note that pairs of markers can be used to mark the start and end of a sub-pattern of flexible length. It is often convenient to enclose the sub-pattern in parentheses (if necessary) and use zero-width assertions to set the markers. In order to extract multi-word noun compounds, we could change our NP pattern as follows:

  MACRO np($0=StartNoun $1=EndNoun $2=MarkAdj)
  (
    [pos="DT"]? [pos="RB"]? $2[pos="JJ.*"]* $0[::] $1[pos="NN.*"]+
  )
  ;
  

  Due to the matching rules, the marker indicated by $1 will be set to the last noun in the sequence (which may be identical to the first noun marked by $0). Keep in mind that /np[] only matches a single noun token unless it is embedded in a larger query or the matching strategy is set to longest.